-- ### Replace "MY.REMOTE.ORACLE.DATABASE" with the actual linked server name

-- ### Prepare stats
IF OBJECT_ID('tempdb..#TableStats') IS NOT NULL DROP TABLE #TableStats;

CREATE TABLE #TableStats (
	ObjectId int,
	TableName varchar(100),
	RowCountMS int,
	RowCountOracle int,
);

-- ### Gather stats
PRINT 'Gathering table stats...'
DECLARE @SQLCommand nvarchar(2000) = '
	DECLARE @Pos AS int = CHARINDEX(''.'', ''?'');
	DECLARE @Schema sysname = SUBSTRING(''?'', 2, @Pos - 3);
	DECLARE @Table sysname = SUBSTRING(''?'', @Pos + 2, LEN(''?'') - @Pos - 2);
	DECLARE @SQLOpenQuery nvarchar(1000) = 
		N''DECLARE @x AS int; SELECT @x=1 FROM OPENQUERY([MY.REMOTE.ORACLE.DATABASE], ''''SELECT 1 FROM all_objects WHERE OWNER = '''''''''' + @Schema + '''''''''' AND OBJECT_NAME = '''''''''' + @Table + '''''''''''''')''
	DECLARE @SQLUpdate nvarchar(1000) = 
		N''UPDATE #TableStats SET RowCountOracle = (SELECT vOracle.RowCountOracle FROM OPENQUERY([MY.REMOTE.ORACLE.DATABASE], ''''SELECT COUNT(*) AS RowCountOracle FROM '' + @Schema + ''.'' + @Table + '''''') AS vOracle) WHERE TableName = ''''?'''''';
	-- PRINT @SQLUpdate
	PRINT ''?...''

	INSERT INTO #TableStats (ObjectId, TableName, RowCountMS, RowCountOracle)
	SELECT OBJECT_ID(''?''), ''?'', (SELECT COUNT(*) FROM ?), -1;

	EXEC sp_executeSQL @SQLOpenQuery;
	IF @@RowCount > 0 
	BEGIN
		EXEC sp_executeSQL @SQLUpdate;
	END			
'
PRINT 'EXEC sp_MSforeachtable using the following command:'
PRINT @SQLCommand;
EXEC sp_MSforeachtable @SQLCommand;
PRINT 'Finished!'

-- ### Print stats, RowCountOracle = -1 => Table doesn't exist in Oracle
SELECT *
FROM #TableStats AS s
WHERE
-- No SSMA-Objects
s.TableName NOT LIKE '%ssma_oracle%'
-- only tables with primary keys
AND EXISTS (
	SELECT *
	FROM sys.indexes AS idxPK
	WHERE idxPK.object_id = s.ObjectId
	AND idxPK.is_primary_key = 1
)
-- only differences
AND s.RowCountMS <> s.RowCountOracle
ORDER BY s.TableName;